Начнём, пожалуй, с главного окна приложения, создаётся оно теперь так:

Исходник main.cpp

#include <QGuiApplication>
#include <QtQml>
#include <QtQuick/QQuickItem>
#include <QtQuick/QQuickWindow>
#include <QQmlComponent>

int main(int argc, char *argv[])
{
    QGuiApplication app(argc, argv);
    QQmlEngine engine;
    QQmlComponent component(&engine);
    component.loadUrl(QUrl("qml/WORKYS5/main.qml"));
    QObject *topLevel = component.create();
    QQuickWindow *window = qobject_cast<QQuickWindow *>(topLevel);
    window->show();
    return app.exec();
}

Исходник main.qml

import QtQuick 2.1
import QtQuick.Controls 1.0
import QtQuick.Layouts 1.0

ApplicationWindow {
    id: app
    title: "WORKYS 5"
    Rectangle {
        anchors.fill: parent
        color: "red"
    }
}

Так же требует изменений .pro файл проекта, выглядеть должен примерно так:

# Add more folders to ship with the application, here
folder_01.source = qml/WORKYS5
folder_01.target = qml
DEPLOYMENTFOLDERS = folder_01

QT += quick
QML_IMPORT_PATH =
SOURCES += main.cpp \
    initter.cpp \
    imageprovider.cpp \
    test.cpp

HEADERS += \
    initter.h \
    imageprovider.h \
    test.h \
    plugininterface.h

OTHER_FILES += \
    qml/WORKYS5/main.qml \
    qml/WORKYS5/Products.qml \
    TestDelegate.qml \
    qml/WORKYS5/MButton.qml

defineTest(qtcAddDeployment) {
    for(deploymentfolder, DEPLOYMENTFOLDERS) {
        item = item$${deploymentfolder}
        greaterThan(QT_MAJOR_VERSION, 4) {
            itemsources = $${item}.files
        } else {
            itemsources = $${item}.sources
        }
        $$itemsources = $$eval($${deploymentfolder}.source)
        itempath = $${item}.path
        $$itempath= $$eval($${deploymentfolder}.target)
        export($$itemsources)
        export($$itempath)
        DEPLOYMENT += $$item
    }

    MAINPROFILEPWD = $$PWD
    win32 {
        copyCommand =
        for(deploymentfolder, DEPLOYMENTFOLDERS) {
            source = $$MAINPROFILEPWD/$$eval($${deploymentfolder}.source)
            source = $$replace(source, /, \\)
            sourcePathSegments = $$split(source, \\)
            target = $$OUT_PWD/$$eval($${deploymentfolder}.target)/$$last(sourcePathSegments)
            target = $$replace(target, /, \\)
            target ~= s,\\\\\\.?\\\\,\\,
            !isEqual(source,$$target) {
                !isEmpty(copyCommand):copyCommand += &&
                isEqual(QMAKE_DIR_SEP, \\) {
                    copyCommand += $(COPY_DIR) \"$$source\" \"$$target\"
                } else {
                    source = $$replace(source, \\\\, /)
                    target = $$OUT_PWD/$$eval($${deploymentfolder}.target)
                    target = $$replace(target, \\\\, /)
                    copyCommand += test -d \"$$target\" || mkdir -p \"$$target\" && cp -r \"$$source\" \"$$target\"
                }
            }
        }
        !isEmpty(copyCommand) {
            copyCommand = @echo Copying application data... && $$copyCommand
            copydeploymentfolders.commands = $$copyCommand
            first.depends = $(first) copydeploymentfolders
            export(first.depends)
            export(copydeploymentfolders.commands)
            QMAKE_EXTRA_TARGETS += first copydeploymentfolders
        }
    }

    export (ICON)
    export (INSTALLS)
    export (DEPLOYMENT)
    export (LIBS)
    export (QMAKE_EXTRA_TARGETS)
}

qtcAddDeployment(DEPLOYMENTFOLDERS);

Пока что весь в делах и больше расписывать времени нет.

Впринципе, этого должно хватить, для начала.